int NUM_AGENT_TICKETS=5;
float AGENT_MAX_SPEED=2.0;

final class Agent{
  float x;
  float y;
  float vx;
  float vy;
  Ticket[] tickets;

  Agent(){
    x=random(WIDTH);
    y=random(HEIGHT);
    vx=random(6)-3;
    vy=random(6)-3;
    tickets=new Ticket[NUM_AGENT_TICKETS];
    for (int i=0; i<tickets.length; i++)
    {
      tickets[i]=new Ticket();
    }  
  }
  void update(){
    if (all_equal()) { 
      return; 
    }
    vx+=random(1.0)-0.5;
    vy+=random(1.0)-0.5;
    if (vx>AGENT_MAX_SPEED) { 
      vx=AGENT_MAX_SPEED; 
    }
    if (vy>AGENT_MAX_SPEED) { 
      vy=AGENT_MAX_SPEED; 
    }
    if (vx<-AGENT_MAX_SPEED) { 
      vx=-AGENT_MAX_SPEED; 
    }
    if (vy<-AGENT_MAX_SPEED) { 
      vy=-AGENT_MAX_SPEED; 
    }
    x+=vx;
    y+=vy;
    if (x<0) {
      x=0; 
      vx=-vx;
    }
    if (y<0) {
      y=0; 
      vy=-vy;
    }
    if (x>WIDTH-TICKET_WIDTH) {
      x=WIDTH-TICKET_WIDTH; 
      vx=-vx;
    }
    if (y>HEIGHT-TICKET_HEIGHT*tickets.length) {
      y=HEIGHT-TICKET_HEIGHT*tickets.length; 
      vy=-vy;
    }
  }
  void draw(){
    pushMatrix();
    translate(x,y);
    for (int i=0; i<tickets.length; i++)
    {
      translate(0,TICKET_HEIGHT);
      tickets[i].draw();
    }  
    popMatrix();
  }

  boolean collides_with(Agent b)
  {
    return (
    abs(x-b.x)<TICKET_WIDTH
      &&
      abs(y-b.y)<TICKET_HEIGHT*tickets.length
      );
  }

  int discard_ticket()
  {
    // count up colours of each ticket
    int[] colour_counts=new int[TICKET_COLOURS.length];
    for (int i=0; i<tickets.length; i++)
    {
      colour_counts[tickets[i].colour]++;
    }
    for (int mc=1; mc<=tickets.length; mc++)
    {
      // find a colour with only mc tickets here
      for (int i=0; i<colour_counts.length; i++)
      {
        if (colour_counts[i]==mc)
        {
          // find a ticket coloured i
          for (int j=0; j<tickets.length; j++)
          {
            if (tickets[j].colour==i)
            {
              return j;
            }
          }
        }
      }
    }
    return -1;
  }
  boolean all_equal()
  {
    for (int i=1; i<tickets.length; i++)
    {
      if (tickets[i-1].colour!=tickets[i].colour)
      {
        return false;
      }
    }
    return true;
  }
  void stop_if_all_equal()
  {
    if (all_equal())
    {
      vx=0.0;
      vy=0.0;
    }
  }
  void repel(Agent b)
  {
    if (abs(x-b.x)>abs(y-b.y))
    {
      if (x > b.x)
      {
        vx=abs(vx);
        b.vx=-abs(b.vx);
      }
      else if (x < b.x)
      {
        vx=-abs(vx);
        b.vx=abs(b.vx);
      }
    }
    else
    {
      if (y > b.y)
      {
        vy=abs(vy);
        b.vy=-abs(b.vy);
      }
      else if (y < b.y)
      {
        vy=-abs(vy);
        b.vy=abs(b.vy);
      }
    }
  }
};